按照指定字符拆分

shiyiming

举例如下：
[code:hpyezk89]data want;
input ch $20.;
cards;
3*2.5*3
1*1*0.7
1.5*1.5*1.5
1.5*1*1
1.5*1*0.5
1.5
1.3*0.7*0.5
1.5*1*0.8
0.7*0.5
;
run;
/* 想以'*' 为分割标记，分为三个变量，x1,x2,x3,*/
/* 若有0.7*0.5 则表示为x1,x2                 */
/* 若有1.5      则表示为x1；                 */[/code:hpyezk89]

shiyiming

有一个语句可以参考，但有点欠缺。
[code:1ddqlfnj]b1=input(substr(_col22,1,index(a,'*')-1),8.); [/code:1ddqlfnj]
但问题是在“*”分割的字符不是等长度的，所以以上语句没法使用，还望大侠回复！

shiyiming

用scan函数
x1=scan(ch,1,"*");
x2=scan(ch,2,"*");
...

shiyiming

[code:2vh3hxzo]proc sql noprint;
        select max(countc(ch,'*'))+1 into :n_max from want;
quit;
data result;
        set want;
        n=countc(ch,'*')+1;
        array x{&n_max.} $32;
        do i=1 to n;
                x(i)=scan(ch,i,'*');
        end;
        drop n i;
run;[/code:2vh3hxzo]

shiyiming

为什么不一开始在读取观测的时候处理了？
[code:8vauqsu4]
data want;
        infile cards dlm='*' truncover;
        input x1 x2 x3 ;
cards;
3*2.5*3
1*1*0.7
1.5*1.5*1.5
1.5*1*1
1.5*1*0.5
1.5
1.3*0.7*0.5
1.5*1*0.8
0.7*0.5
;
run;[/code:8vauqsu4]