用SAS获取指定地方的地图 - SAS中文论坛

%sas_getMap("Tianhe Coach Terminal Station, Guangzhou, Guangdong","C:\temp\tianhe.png")

复制代码

%sas_getMap("Tiananmen, Beijing, China","C:\temp\beijing.png")

复制代码

%sas_getMap("Canton tower, Guangdong, China","C:\temp\tower.png",zoom=18,width=640,height=640)

复制代码

%macro sas_getMap(address,img_filename,zoom=15,width=640,height=520);
data _null_;
length url $ 2048;
url = catt( 'http://maps.googleapis.com/maps/api/staticmap?markers=', &address,
'&zoom=', &zoom, '&size=', &width, 'x', &height, '&sensor=false');
url = transtrn(trim(url), ' ', '%20');
call symputx('REQUEST_URL', url);
run;
filename img_fref &img_filename;
proc http out = img_fref url = "%superq(REQUEST_URL)" method = "GET"
ct="application/x-www-form-urlencoded";
run;
%mend;

复制代码

%macro sas_getMap;
/*URL设置，参数设置，空格替换为20%*/
data _null_;
length url $ 2048;
url = catt('http://maps.googleapis.com/maps/api/staticmap?markers=', &address,
'&zoom=12','&size=', &width, 'x', &height,'&sensor=false');
url = transtrn(trim(url), ' ', '%20');
call symputx('REQUEST_URL', url);
run;
/*图片输出文件*/
filename img_fref &img_filename;
/*临时文件：保存从谷歌地图服务器返回的header*/
filename hdr_out temp;
proc http out = img_fref url = "%superq(REQUEST_URL)" headerout = hdr_out method = "GET"
ct="application/x-www-form-urlencoded";
run;
/*通过返回的header来判断地图是否获取成功，成功返回0，否则返回谷歌地图服务器返回的值*/
data _null_;
infile hdr_out;
input;
if prxmatch('/^HTTP\/\S+\s+\d+/', _infile_);
status = scan(_infile_, 2, ' ');
/*200表示成功，其他值都为失败*/
if status = '200' then
call symputx('STATUS', 0);
else
call symputx('STATUS', status);
stop;
run;
%mend;
/*将宏程序封装到函数sas_getMap中*/
proc fcmp outlib=sasuser.funcs.web;
function sas_getMap(address $, width, height, img_filename $);
length status 8;
rc = run_macro('sas_getMap', address, width, height, img_filename, status);
return (status);
endsub;
quit;
/*生成包含地址的数据集*/
data addresses;
length name $ 32 address $ 128;
infile datalines truncover;
input name address $128.;
datalines;
SAS SAS Campus Dr., Cary, NC 27513
YMCA 1603 Hillsborough St., Raleigh, NC 27605
NCSU Joyner Visitor Center, NC State University, Raleigh, NC 27695-7504
UNC-CH UNC Visitor Center, 250 East Franklin Street, Chapel Hill, NC
;
options cmplib=sasuser.funcs;
/*通过函数sas_getMap获取地图图片*/
data _null_;
set addresses;
/* <Imagine report generation code here> */
rc = sas_getMap(address, 160, 120, catt('c:\temp\', name, '.png'));
if rc then
putlog 'ERROR: Could not get map for ' name;
run;

复制代码

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>静态图与URLAPI结合示例</title>
<body>
<a href='http://api.map.baidu.com/geocoder?address=上海虹桥机场&output=html' target='_blank'> <img style="margin:2px" width="400" height="300" src="http://api.map.baidu.com/staticimage?
width=400&height=300&zoom=11¢er=上海虹桥机场" />
</a>
</body>
</html>

复制代码